2 REM COPYRIGHT 1987 COMPUTE! PUBLICATIONS, INC. - ALL RIGHTS RESERVED
4 REM DRIVE#  PRINTER#  REVERSE ON  REVERSE OFF  SPACER
6 DR=8:PR=4:RV$=CHR$(18):RO$=CHR$(146):SP$="*"
8 S1$=" ":FORI=1TO21:SX$=SX$+S1$:NEXT:S6$=LEFT$(SX$,6):NA$=CHR$(0)
10 PRINTCHR$(142)CHR$(8):DIMM(12),Y$(4),Q$(6),H$(25),C$(6),M$(4)
12 FORI=1TO12:READM(I):NEXT:READD$:D$=D$+" "+D$+" "+D$
14 FORI=1TO4:READA$,B$,C$:M$(I)=S6$+A$+LEFT$(SX$,15)+B$+LEFT$(SX$,15)+C$:NEXT
16 FORI=1TO31:Q$=Q$+RIGHT$(STR$(I),2)+" ":NEXT:READF$
18 FM$=CHR$(17)
20 REM --- PARSE YEAR ---
22 PRINTCHR$(147)"   COPYRIGHT 1987 COMPUTE! PUB., INC."
24 PRINTTAB(10)"ALL RIGHTS RESERVED"
26 PRINTFM$TAB(13)"CALENDAR MAKER":PRINTTAB(13)"--------------"FM$
28 INPUT"WHAT YEAR WOULD YOU LIKE";Y$:IFLEN(Y$)=2THENY$="19"+Y$
30 Y=VAL(Y$):IFY<1900ORY>2050GOTO26
32 FORJ=1TO4:FORI=.TO4:Y$(J)=Y$(J)+MID$(F$,I*10+VAL(MID$(Y$,J,1))+1,1)
34 NEXT:NEXT
36 REM --- GET TEXT ---
38 PRINTFM$"ENTER TEXT (254 CHAR. MAX).":PRINTFM$">> ";
40 GETA$:IFA$=""THEN40
42 IFA$=CHR$(13)GOTO52
44 IFA$=CHR$(20)ANDN$>""THENN$=LEFT$(N$,LEN(N$)-1):GOTO48
46 ON-(A$<" "OR(A$>CHR$(127)ANDA$<CHR$(160))ORLEN(N$)=254)GOTO40:N$=N$+A$
48 PRINTA$;:GOTO40
50 REM --- REVERSE? ---
52 PRINT:PRINTFM$"REVERSE YEAR HEADING? (Y/N) ":GOSUB120
54 ON-(A$="Y")-(A$="N")*2GOTO60,56:GOTO52
56 RV$=NA$:RO$=NA$:S1$=SP$
58 REM --- WHERE? ---
60 PRINTFM$"(S)CREEN, (P)RINTER, OR (D)ISK?":GOSUB120
62 ON-(A$="S")-(A$="P")*2-(A$="D")*3GOTO76,64,70:GOTO52
64 PRINTFM$"SET UP PRINTER AND HIT ANY KEY..."
66 GETB$:IFB$=""THEN66
68 GOTO76
70 OPEN15,DR,15,"I0:":OPEN3,DR,3,"0:"+Y$+" CALENDAR,S,W"
72 INPUT#15,B$,C$:IFB$<"19"GOTO80
74 CLOSE3:CLOSE15:PRINTFM$"DISK ERROR -- "B$" "C$:FORI=1TO2000:NEXT:GOTO60
76 OPEN3,3-((A$="P")+(PR=5))
78 REM --- PRINT HEADING ---
80 PRINTFM$"WORKING...":FORI=1TOINT(255/(LEN(N$)+1)):AA$=AA$+N$+S1$:NEXT
82 FORI=1TO17STEP4:P=.:FORK=1TO4:B=VAL(MID$(Y$(K),I/4+1,1)):FORL=2TO.STEP-1
84 IF(BAND2^L)=.THENFORJ=ITOI+3:H$(J)=H$(J)+NA$+"     "+NA$:NEXT:GOTO88
86 FORJ=ITOI+3:H$(J)=H$(J)+RV$+MID$(AA$,J+P*5,5)+RO$:NEXT
88 P=P+1:NEXT:NEXT:NEXT:A$="  ":L=21:FORI=1TO20
90 N$=LEFT$(H$(I),L)+A$+MID$(H$(I),22,L)+A$+MID$(H$(I),43,L)+A$+RIGHT$(H$(I),L)
92 PRINT#3,S6$+" "+N$:NEXT:PRINT#3:PRINT#3:PRINT#3:M=1
94 REM --- PRINT CALENDAR ---
96 Z=INT(365.25*(Y-1))+INT(30.6*(M+13))-1
98 FORI=1TO10STEP3:FORJ=ITOI+2:D=M(M)+(Y/4=INT(Y/4))*(M=2)
100 IFRIGHT$(Y$,2)="00"THENYC=VAL(LEFT$(Y$,2)):D=D-(YC/4<>INT(YC/4))*(M=2)
102 Z=Z-INT(Z/7)*7:Q$(1)=LEFT$(LEFT$(SX$,3*Z)+Q$,21):L=7-Z:K=1:A=.
104 K=K+1:B=A:A=(L+7+D-ABS(L+7-D))/2:Z=A-B
106 Q$(K)=LEFT$(MID$(Q$,3*L+1,3*Z)+SX$,21)
108 L=L+7:ON-(A<D)GOTO104:IFK=5THENQ$(6)=SX$
110 FORK=1TO6:C$(K)=C$(K)+"  "+Q$(K):Q$(K)=SX$:NEXT:M=M+1:NEXT
112 PRINT#3,S6$+M$(J/3):PRINT#3:PRINT#3,S6$+D$:FORK=1TO6
114 PRINT#3,"     "+C$(K):C$(K)="":NEXT:PRINT#3:NEXT:FORI=1TO3:PRINT#3:NEXT
116 CLOSE3:CLOSE15:PRINTFM$"DONE...HIT ANY KEY TO CONTINUE":GOSUB120:PRINT
118 PRINTFM$"MAKE ANOTHER? (Y/N)":GOSUB120:ON-(A$<>"Y")GOTO126:RUN
120 GETA$:IFA$=""THEN120
122 RETURN
124 REM --- DATA ---
126 DATA31,28,31,30,31,30,31,31,30,31,30,31
128 DATA" SU MO TU WE TH FR SA "
130 DATA" JANUARY","FEBRUARY","  MARCH","  APRIL ","  MAY   ","   JUNE"
132 DATA"  JULY  "," AUGUST ","SEPTEMBER"," OCTOBER","NOVEMBER","DECEMBER"
134 DATA"72775777775611544155527377717752411151517777177177"